home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Cream of the Crop 25
/
Cream of the Crop 25.iso
/
bbs
/
con_005c.zip
/
CONCORD.RAR
/
SCRIPT.RAR
/
TIMEBANK.SCR
< prev
next >
Wrap
Text File
|
1997-04-25
|
5KB
|
139 lines
; TIMEBANK.SCR : Time bank script
;
; Users can save the remaining time and download limit for today
; to the bank for later use.
;
; This script is called from GOODBYE.MNU menu.
;
; Modify %MAXTIME% and %MAXLIMIT% settings to define the maximum
; time bank account values.
;
; Modify %MAXLOANTIME% and %MAXLOANLIMIT% settings if you want
; to allow loading from the time bank. (Zero means that loaning
; is not possible.)
var %SELECTION% = NUMBER
var %VALUE% = NUMBER
var %TEMP% = NUMBER
var %MAX% = NUMBER
var %MAXTIME% = NUMBER
var %MAXLIMIT% = NUMBER
var %MAXLOANTIME% = NUMBER
var %MAXLOANLIMIT% = NUMBER
;
; MAXIMUM TIME BANK ACCOUNT VALUES
;
set %MAXTIME% = 180
set %MAXLIMIT% = 2000
;
; TIME BANK LOANING SETTINGS
;
set %MAXLOANTIME% = 0
set %MAXLOANLIMIT% = 0
:START
write "^C14,0;^E1;Welcome to the bank of El Paso!^M;^M;"
write "^C15,0;Currently, you have ^C11,0;@TIME_LEFT@ ^C15,0;minutes "
write "and ^C11,0;@LIMIT_LEFT@ ^C15,0;kilobytes.^M;^M;"
write "^C15,0;You have on your account :^M;"
write "^C15,0;Time .........^C7,0; : "
write "^C11,0;@TIMEINBANK@:05 ^C7,0;min^M;"
write "^C15,0;Download limit^C7,0; : "
write "^C11,0;@DLLIMITINBANK@:05^C7,0;K^M;^M;"
write "^C7,0;(^C14,0;D^C7,0;) ^C15,0;Deposit time "
write "^C7,0;(^C14,0;A^C7,0;) ^C15,0;Deposit limit^M;"
write "^C7,0;(^C14,0;W^C7,0;) ^C15,0;Withdraw time "
write "^C7,0;(^C14,0;S^C7,0;) ^C15,0;Withdraw limit^M;"
write "^C7,0;(^C14,0;R^C7,0;) ^C15,0;Redraw screen "
write "^C7,0;(^C14,0;Q^C7,0;) ^C15,0;Exit bank^M;"
write "^C14,0;Your command "
write "^C7,0;(^C14,0;~2D~3W~4A~5S~1R~6Q^C7,0;) : ^W;^M;^M;"
set %SELECTION% = @ANSWER@
if (%SELECTION% = 2)
gosub DEPOSIT_TIME
end
if (%SELECTION% = 3)
gosub WITHDRAW_TIME
end
if (%SELECTION% = 4)
gosub DEPOSIT_LIMIT
end
if (%SELECTION% = 5)
gosub WITHDRAW_LIMIT
end
if (%SELECTION% = 6)
goto OUT
end
goto START
:DEPOSIT_TIME
set %MAX% = (%MAXTIME%-@TIMEINBANK@)
if ((%MAX% < 0) or (%MAX% > @TIME_LEFT@))
set %MAX% = @TIME_LEFT@
end
if (%MAX% > @EVENT_MINUTES@)
set %MAX% = @EVENT_MINUTES@
end
write "^C12,0;How many minutes do you want to deposit "
write "(max %MAX%) : ^C14,1;^L3;^C15,0;^M;"
set %VALUE% = @ANSWER@
if ((%VALUE% > 0) AND (%VALUE% <= %MAX%))
set %TEMP% = (@TIME_LEFT@-%VALUE%)
set @TIME_LEFT@ = %TEMP%
set %TEMP% = (@TIMEINBANK@+%VALUE%)
set @TIMEINBANK@ = %TEMP%
end
return
:WITHDRAW_TIME
set %MAX% = (@TIMEINBANK@+%MAXLOANTIME%)
set %TEMP% = (%MAX%+@TIME_LEFT@)
if (%TEMP% >= @EVENT_MINUTES@)
set %MAX% = (@EVENT_MINUTES@-@TIME_LEFT@)
end
write "^C12,0;How many minutes do you want to withdraw "
write "(max %MAX%) : ^C14,1;^L3;^C15,0;^M;"
set %VALUE% = @ANSWER@
if ((%VALUE% > 0) AND (%VALUE% <= %MAX%))
set %TEMP% = (@TIME_LEFT@+%VALUE%)
set @TIME_LEFT@ = %TEMP%
set %TEMP% = (@TIMEINBANK@-%VALUE%)
set @TIMEINBANK@ = %TEMP%
end
return
:DEPOSIT_LIMIT
set %MAX% = (%MAXLIMIT%-@DLLIMITINBANK@)
if ((%MAX% < 0) or (%MAX% > @LIMIT_LEFT@))
set %MAX% = @LIMIT_LEFT@
end
write "^C12,0;How many kilobytes do you want to deposit "
write "(max %MAX%) : ^C14,1;^L4;^C15,0;^M;"
set %VALUE% = @ANSWER@
if ((%VALUE% > 0) AND (%VALUE% <= %MAX%))
set %TEMP% = (@LIMIT_LEFT@-%VALUE%)
set @LIMIT_LEFT@ = %TEMP%
set %TEMP% = (@DLLIMITINBANK@+%VALUE%)
set @DLLIMITINBANK@ = %TEMP%
end
return
:WITHDRAW_LIMIT
set %MAX% = (@DLLIMITINBANK@+%MAXLOANLIMIT%)
write "^C12,0;How many kilobytes do you want to withdraw "
write "(max %MAX%) : ^C14,1;^L4;^C15,0;^M;"
set %VALUE% = @ANSWER@
if ((%VALUE% > 0) AND (%VALUE% <= %MAX%))
set %TEMP% = (@LIMIT_LEFT@+%VALUE%)
set @LIMIT_LEFT@ = %TEMP%
set %TEMP% = (@DLLIMITINBANK@-%VALUE%)
set @DLLIMITINBANK@ = %TEMP%
end
return
:OUT
quit